// splitter.txt - Exactly like basicnpc.txt, with one big difference. When it
// dies, it does not give xp or drop loot. Instead, it poofs and spawns other 
// monsters (which give xp and loot as normal).

// The creatures spawned have the default script for the creature. If that
// default script is splitter.txt, you can create an infinite chain of kills.
// This can be funny.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The creature type to spawn. If left at 0, defaults to spawning the
//     same sort of creature.
//   Cell 5 - Number of creatures to spawn. If left at 0, defaults to 2.

begincreaturescript;

variables;

short i,target;
short num_to_spawn = 2;
short type_to_spawn;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	
	type_to_spawn = creature_type(ME);
	if (get_memory_cell(4) > 0)
		type_to_spawn = get_memory_cell(4);
		
	if (get_memory_cell(5) > 0)
		num_to_spawn = get_memory_cell(5);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
	print_named_str(ME,"splits up!");
	i = 0;
	while (i < num_to_spawn) {
		place_monster(my_loc_x(),my_loc_y(),type_to_spawn,0);
		i = i + 1;
		}
	erase_char(ME);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;